Another newbie's program to check

[ciphros]

OK, I think I might have my program set up for basic operation of my tank, but would like those of you with more experience with the commands to make sure there's nothing I've done that is of concern.

Here's the program with notes on areas I'm not entirely sure about:

//return pump (dolphin ampmaster 3700), don't have a closed loop (may add power heads for extra current and back-up if pump should go off)
PMP#-A01

//Three 400W XM 10000K Metal Halide bulbs and VHO Actinics
MH1$-A02
MH2$-A03
MH3$-A04
VHO$-A05

HET%-A06 //Heater in the sump
COL%-A07 //Chiller, water supplied through Sea Swirls
FUG$-A08 //Fuge light
ALM&-A09 //Alarm set as ficticious timer as per original settings

If Time > 00:00 Then PMP ON
If Time > 07:30 Then VHO ON
If Time > 22:00 Then VHO OFF
If Time > 10:00 Then MH1 ON
If Time > 18:00 Then MH1 OFF
If Time > 12:00 Then MH2 ON
If Time > 20:00 Then MH2 OFF
If Time > 11:00 Then MH3 ON
If Time > 19:00 Then MH3 OFF
If Time > 21:00 Then FUG ON
If Time > 07:29 Then FUG OFF
If Temp > 80.0 Then COL ON
If Temp < 79.5 Then COL OFF

//if I understand this command correctly, this should mean that once the chiller has cycled, it will not turn on again for 15 minutes regardless of temp change?
Max Change 015 M Then COL OFF

If Temp < 78.7 Then HET ON
If Temp > 79.0 Then HET OFF

//This section I think helps me control temp by either turning off or on my lights, did I get this right?
If Temp > 80.8 Then MH1 OFF
If Temp > 81.0 Then MH3 OFF
If Temp > 81.2 Then MH2 OFF
If Temp > 81.4 Then VHO OFF
If Temp < 77.0 Then MH2 ON
If Temp < 76.6 Then MH3 ON
If Temp < 76.4 Then MH1 ON

If FeedA 000 Then PMP OFF

//Interlocks to keep chiller and heater from running during water changes (when I manually shut off the PMP timer, does this work for manual shut off of the pump?)
If Timer PMP = OFF Then COL OFF
If Timer PMP = OFF Then HET OFF

If Time > 00:00 Then ALM OFF
If pH > 08.50 Then ALM ON
If pH < 08.00 Then ALM ON
If Temp < 76.0 Then ALM ON
If Temp > 81.5 Then ALM ON

//having this statement will keep the alarm on until I respond to it right? Is there a way to be able to have it reset via the web, or would I be better off just having the alarm turn off after power has been back on for 10 min. by changing to 'If Power 010 Then ALM ON'?
If Power 000 Then ALM ON

//Is this right, or do these statments need to be OFF? Didn't completely understand what the idea was here. I'm trying to stagger restart of my devices after a power failure.
If Power 000 Then PMP ON
If Power 001 Then VHO ON
If Power 003 Then COL ON
If Power 010 Then MH1 ON
If Power 020 Then MH2 ON
If Power 030 Then MH3 ON

Thanks for the help! Can't wait to get this thing running on my system, it's an awesome product!

 

[dhoch]

A couple of comments:

1) ON the heating turning off the lights statements:
If Temp > 80.8 Then MH1 OFF
If Temp > 81.0 Then MH3 OFF
If Temp > 81.2 Then MH2 OFF
If Temp > 81.4 Then VHO OFF
If Temp < 77.0 Then MH2 ON
If Temp < 76.6 Then MH3 ON
If Temp < 76.4 Then MH1 ON

Instead do this

If Temp > 80.8 Then MH1 OFF
If Temp > 81.0 Then MH3 OFF
If Temp > 81.2 Then MH2 OFF
If Temp > 81.4 Then VHO OFF
Max Change 030 M Then MH1 OFF
Max Change 030 M Then MH2 OFF
Max Change 030 M Then MH3 OFF

Otherwise one cool night you'll get those halides coming on (not sure you want that)

I'm not sure teh power statements work... I think you want to reverse them to off (so that for example MH1 will be off for 10 mins after power failure).

Yes your use of max change seems ok...

overall a couple of little issues but should be good.

Dave

 

[dougchambers]

Dave is right, you need to change your Power statements to keep things off the set time after power is restored;

If Power 000 Then PMP OFF
If Power 001 Then VHO OFF
If Power 003 Then COL OFF
If Power 010 Then MH1 OFF
If Power 020 Then MH2 OFF
If Power 030 Then MH3 OFF

 

[ciphros]

Thanks guys, that's what I wasn't sure about on the power statements.

Dave, on the max change commands, what exactly does that do? I'm rusty on my programming logic. Do they tell the lights that the temp needs to be that high for 30 min. before the lights go out, or does it tell them that if they do come on, then go back off, they need to stay off for 30 min. before coming back on?

Also, just to clarify, the 2nd half of that light statement, I was actually wanting to use the halides to heat (should my pump shut down and neither heater nor chiller were to be acting on the tank for a period of time). Is that not a good idea, or is there a better way of doing it?

 

[dhoch]

Your better off just dealing with the alarm.. if the temp get's that low somethings wrong...

The max change commands cause a device not to change it's status for a set amount of time...

Max Change 030 M Then MH1 OFF

this statement means MH1 will not change from off status till 30 mins have passed (very helpful if your temp is fulctuating right aroudn a border you don't want that MH switching on and off).

Dave

 

[ciphros]

Thanks, I'll make the changes you guys have suggested and connect it to the tank (but keen the control on timers as they are at the moment so I can monitor the performance of things for a day or two. Then, I'll hook up the DC8 and get things running!