post your program here

[jnb]

or just get one of those newer electroninc timers that can be programmed for each day

but it seems like if your going to add alk it would be better to do as RussM says - more even application

<a href=showthread.php?s=&postid=15045215#post15045215 target=_blank>Originally posted</a> by RussM
No can do... could you do 2 or 3 minutes daily instead?

 

[dodwyer]

Newbie Program

Newbie Program

Just finished up with the Ac-Jr program, used Ken's program to check it. Let me know if you see any issues, thanks in advance.

LT1$-A01 = 400W MH #1
LT2$-A02 = 400W MH #2
LT3$-A03 = T5 Bank
LT4$-A04 = Fuge Light
FN1%-A05 = Fuge Fan
CHL%-A06 = Chiller
HET%-A07 = Heater
FN2%-A08 = Canopy Fan


If Time > 17:00 Then LT2 ON
If Time > 21:00 Then LT2 OFF
If Time > 16:00 Then LT3 ON
If Time > 22:00 Then LT3 OFF
If Time > 06:00 Then LT4 ON
If Time > 14:00 Then LT4 OFF

If Time > 17:00 Then FN2 ON
If Time > 21:00 Then FN2 OFF

If Temp > 78.3 Then FN1 ON
If Temp > 81.0 Then FN1 OFF
If Temp < 78.0 Then FN1 OFF
Max Change 020 M Then FN1 OFF
If Temp > 78.5 Then FN2 ON
If Temp > 81.0 Then FN2 OFF
If Temp < 78.0 Then FN2 OFF
Max Change 020 M Then FN2 OFF
If Temp > 78.8 Then CHL ON
If Temp > 81.0 Then CHL OFF
If Temp < 76.0 Then CHL OFF
If Temp < 78.0 Then CHL OFF
Max Change 020 M Then CHL OFF
If Temp < 77.7 Then HET ON
If Temp > 80.0 Then HET OFF
If Temp > 78.0 Then HET OFF
Max Change 020 M Then HET OFF
If Temp > 80.0 Then LT1 OFF
Max Change 020 M Then LT1 OFF
If Temp > 80.0 Then LT2 OFF
Max Change 020 M Then LT2 OFF
If Temp > 80.0 Then LT3 OFF
Max Change 020 M Then LT3 OFF
If Temp > 80.0 Then LT4 OFF
Max Change 020 M Then LT4 OFF

 

[ciphros]

One thing:

If Temp < 76.0 Then CHL OFF
If Temp < 78.0 Then CHL OFF

Redundant, take the first line out, 76 is less than 78, so it's never going to be a factor.

Also, something to think about, rather than having all your lights shut off if the tank hits 80, maybe stagger by 0.2 or so? That way you can reduce the heat load, but still get some light. I'd put the T5's as the last to go off since they add light, but not much heat.

 

[dodwyer]

Good points - thank you

 

[the3dwizard]

I have been running a basic program for a couple of years. However, I travel more now and going out of the country for 10 days this summer so decided I needed to bullet proof my system. Most of my problems have been leaks, etc which the current setup didn't handle. So getting a water flood sensor, setting up web and email access, and reprogramming the AC3 Pro.

Well I think I have been looking at this for too long. So hoping for more pairs of eyes to see if there is anything I have missed. BTW thanks Ken, information on your site has been helpful.

MH1$-A01 // Metal Halide Left
MH2$-A02 // Metal Halide Right
HEF$-A03 // Hood exhaust fan to outside
CLP#-A04 // Powerheads

VH1$-B01 // VHO outside set
VH2$-B02 // VHO inside set
MJ2$-B03 // Maxjet
MN1$-B04 // Moonlight leds

RTN#-B05 // Main pump
KRF#-B06 // Kalk reactor feed via Spectrapure LiterMeter III
KMX#-B07 // Kalk mixer
SPF$-B08 // Sump fans

-B09 // Blanks slots are future expansion
-B10
SKM$-B11 // Skimmer
RRF$-B12 // Reef Relief auto top off

RFL$-D01 // Refugium light 1
RF2$-D02 // refugium light 2
COL%-D03 // Chiller
PB1#-D04 // Phosban Reactor #1
PB2#-D05 // Phosban Reactor #2
-D06
-D07
-D08

DAY&-N01 // Daytime
LOW&-P01 // Refugium below normal level
OVR&-P02 // Refugium level too high
FLD&-P03 // Water sensor

ALM#-A13


// Initialize equipment
If Time > 00:00 Then ALM OFF
If Time > 00:00 Then RTN ON
If Time > 00:00 Then SKM ON
If Time > 00:00 Then CLP ON
If Time > 00:00 Then PB1 ON
If Time > 00:00 Then PB2 ON
If Time > 00:00 Then MJ2 ON
If Time > 00:00 Then DAY OFF

// Check and set switches
If Switch1 OPEN then LOW ON
If Switch1 CLOSED then LOW OFF
If Switch2 OPEN then RE2 OFF
If Switch2 CLOSED then RE2 ON
If Switch3 OPEN then FLD OFF
If Switch3 CLOSED then FLD ON

// Light control section

// Main VHOs
If Sun 000/000 Then VH1 ON
Max Change 001 M Then VH1 OFF
If Timer VH1 = ON Then DAY ON

If Sun 060/-060 Then VH2 ON
Max Change 001 M Then VH2 OFF

// Main MhD
If Sun 120/-130 Then MH1 ON
Max Change 015 M Then MH1 OFF
If Timer MH1 = ON Then DAY ON

If Sun 130/-120 Then MH2 ON
Max Change 015 M Then MH2 OFF

If Time > 00:00 Then RFL ON
If Time > 10:00 Then RFL OFF
If Time > 12:00 Then RFL ON
If Time > 00:00 Then RF2 ON
If Time > 09:00 Then RF2 OFF
If Time > 11:00 Then RF2 ON
If Time > 01:00 Then MN1 OFF
If Time > 18:00 Then MN1 ON

// Temp control section
If Temp > 82.1 Then MH1 OFF
If Temp > 82.3 Then MH2 OFF
If Temp > 82.8 Then VH1 OFF
If Temp > 82.9 Then VH2 OFF
If Temp > 79.6 Then HEF ON
If Temp < 79.5 Then HEF OFF
If Temp > 80.4 Then SPF ON
If Temp < 80.3 Then SPF OFF
If Temp > 81.7 Then COL ON
If Temp < 81.6 Then COL OFF
If Temp > 84 Then COL OFF

// FeedA: main feed
If FeedA 000 Then RTN OFF

// Kalk reactor flow control
If Time > 00:02 Then KRF ON
If Time > 17:00 Then KRF OFF
If pH > 08.45 Then KRF OFF
Max Change 005 M Then KRF OFF

// Stir the kalk reactor 5 minutes
If Time > 18:00 Then KMX ON
If Time > 18:05 Then KMX OFF

// Make sure water levels are topped off
If Time > 18:30 Then RRF ON
If Time > 23:00 Then RRF OFF

// Refugium level too low
If Timer LOW = ON Then RTN OFF
Max Change 005 M Then RTN OFF
If Timer LOW = ON Then RRF ON
If Timer LOW = ON Then COL OFF
If Timer RTN = OFF Then COL OFF

// High water level turn off possible sources
If Timer OVR = ON Then RRF OFF
If Timer OVR = ON Then KRF OFF

// Potential leak shut off possible sources
If Timer FLD = ON Then PB1 OFF
If Timer FLD = ON Then RTN OFF
If Timer FLD = ON Then RRF OFF
If Timer FLD = ON Then KRF OFF

// These alarms are raised all the time but only during the daytime
If Timer LOW = ON Then ALM ON
If Timer DAY = OFF Then ALM OFF

//Alarms no matter what time of day; something potentially really bad
If PH > 8.60 Then ALM ON
If Timer FLD = ON Then ALM ON
If Timer OVR = ON Then ALM ON
If Power 000 Then ALM ON

 

[MplsMan]

can i cut/paste this:
i want to have my alarms do this:
if ph> then 8.6
if temp > then 85*
if return pump shut down

or do i have to program this into the controller.
i've been doing a lot of searching but haven't found anything
this is for my AC3

 

[the3dwizard]

You can turn your alarms on using these lines

If PH > 8.60 Then ALM ON
If Temp > 85 Then ALM ON

The pump flow would be harder to do as there is no pre-built sensor. With the standard set of tools all you can do is set an alarm if your program turns off the pump. For instance I am putting in a flood sensor to detect water leaks. If that happens then I turn off the return pump. This is the code I am going to use.

Timer
RTN#-B05 // Main pump

Program
If Switch3 OPEN then FLD OFF
If Switch3 CLOSED then FLD ON
If Timer FLD = ON Then RTN OFF
If Timer FLD = ON Then ALM ON

BTW I just realized if forgot a temp alarm statement in my program lol

 

[pga7602]

Hi guys,

Can someone proof read this program. I'm going to upload it to my ACJR. Please assume the Chiller will use it's own controller

LT=LIGHT
MON= MOON LIGHT
SKIM= SKIMMER
HET= HEATER
CHL= CHILLER
ALM= ALARM

If Time > 14:00 Then LT1 ON
If Time > 22:00 Then LT1 OFF
If Time > 13:00 Then LT2 ON
If Time > 15:00 Then LT2 OFF
If Time > 20:00 Then LT2 ON
If Time > 23:00 Then LT2 OFF
If Time > 22:55 Then MON ON
If Time > 13:00 Then MON OFF
If Time > 00:00 Then SKM ON
If FeedA 000 Then SKM OFF
If Temp < 76.0 Then HET ON
If Temp > 77.0 Then HET OFF
If Temp > 70.0 Then CHL ON
If Temp < 68.0 Then CHL OFF
If Temp > 84.0 Then LT1 OFF
If Temp > 84.0 Then LT2 OFF
If Time > 00:00 Then ALM OFF
If Temp < 75.0 Then ALM ON
If Temp > 82.0 Then ALM ON

 

[the3dwizard]

You have the potential for having the chiller and heater on at the same time. If something goes wrong with the controller on the chiller then you could have problems. What temperature are you shooting for?

If you were trying for 78 I would do something like these:

If Temp < 76.0 Then HET ON
If Temp < 74 Then ALM ON // Notify me
If Temp > 77.0 Then HET OFF
If Temp > 79.0 Then CHL ON
If Temp > 84 Then CHL OFF // Something may be wrong
If Temp > 83 Then ALM ON // Notify me
If Temp < 77.0 Then CHL OFF

 

[Padrino]

I thought i read somewhere that there was a random events statement? Does anyone use it how does it work?

 

[Deleted member 143833]

Yes, it is the same as OSC statement but use RND (in place of OSC). The controller will generate 2 random values at the beginning of each cycle, run 1 complete on/off cycle and generate 2 new values for the next cycle.

 

[illsquaddotcom]

This is what I'm using for now. Fug on at night, Lights use the seasonal function but I have them pushed back a few hours to adjust for my viewing schedule. I also have a dummy timer set to dose kalk at night but only if the ph is low enough. The only real question I have is the ordering of these commands, I have them grouped for better organization but I think that a better order could be found.... Anybody....

LTB$-A1 blues
LTW$-A2 Whites
FAN%-A4 fan
HET%-A5 heater
KLK#-A6 Aqualifter from Kalk
FUG$-A7 Fuge
ATO#-A8 ato
MON&-E11 Moon lights
MJ2#-A9 MJ MOD
MJ1#-A3 MJ MOD
ALM#-H3 Alarm module
DUM#-H2 Dummy



If Sun 000/000 Then LTB ON
If Sun 060/-090 Then LTW ON
If Temp < RT+-0.4 Then HET ON
If Temp > RT+0.0 Then HET OFF
If Temp > RT+0.6 Then FAN ON
If Temp < RT+0.0 Then FAN OFF
If Temp > RT+2.0 Then LTW OFF
If Moon 000/000 Then MON ON
If Time > 19:30 Then FUG ON
If Time > 05:30 Then FUG OFF
If Time > 00:00 Then MJ2 ON
If FeedA 010 Then MJ1 OFF
If FeedA 000 Then MJ2 OFF
If FeedA 000 Then LTB ON
If Time > 00:00 Then ALM OFF
If Temp < 73.0 Then ALM ON
If Temp > 84.0 Then ALM ON
If pH < 07.90 Then ALM ON
If pH > 08.60 Then ALM ON
If pH > 08.45 Then FUG OFF
If pH > 08.45 Then LTW OFF
If pH > 08.50 Then LTB OFF
If pH > 08.35 Then KLK OFF
OSC 020/240 ON/OFF Then ATO ON
OSC 001/090 ON/OFF Then KLK ON
If Power 045 Then ALM ON
If Power 059 Then DUM ON
If Time > 11:01 Then DUM OFF
If Timer DUM = ON Then KLK OFF
If pH > 08.35 Then KLK OFF

 

[805reef]

Here is my program... my first attempt for my AC3... any feedback would be greatly appreciated. Thanks!

HET%-A1 //Heater
RET#-A2 //Return Pump
SKM#-A3 //Skimmer Pump
ATO#-A4 //ATO System
LT1$-A5 //Outer Lights
LT2$-A6 //Inner Lights
MLT$-A7 //Moon Lights
FUG$-A8 //Fuge Light
CAR#-B9 //Carbon Reactor


IF Temp < 78.5 Then HET ON
IF Temp > 79.5 Then HET OFF
IF Temp > 81.0 Then LT2 OFF
MAX Change 010 M Then LT2 OFF


IF Time > 11:00 Then LT1 ON
If Time > 11:00 Then FUG OFF
If Time > 11:00 Then MLT OFF
IF Time > 12:00 Then LT2 ON
IF Time > 20:00 Then LT2 OFF
IF Time > 21:00 Then LT1 OFF
IF Time > 21:00 Then FUG ON
IF Time > 21:00 Then MLT ON


If Time > 00:00 Then RET ON
If Time > 00:00 Then SKM ON
If Time > 00:00 Then CAR ON

If Time > 06:45 Then ATO ON
If Time > 07:00 Then ATO OFF
If Time > 15:00 Then ATO ON
If Time > 15:30 Then ATO OFF

IF FeedA 005 Then RET OFF
IF FeedB 100 Then RET OFF
IF FeedB 100 Then SKM OFF
IF FeedB 100 Then CAR OFF
IF FeedB 100 Then HET OFF

 

[Deleted member 143833]

IF FeedA 005 Then RET OFF
IF FeedB 100 Then RET OFF
IF FeedB 100 Then SKM OFF
IF FeedB 100 Then CAR OFF
IF FeedB 100 Then HET OFF

I wonder if this is intended; the time value in the Feed statement is an amount of time, in addition to the feed time. Feed time is set in the controller using the keypad. For example, the default FeedA time is 5 minutes so the statement above will have RET off for 10 minutes total (5 for the feed cycle + 5 additional).

 

[RussM]

You could simplify your 'fuge light and moonlight control...

If Time > 00:00 Then MLT ON
If Time > 00:00 Then FUG ON
If Timer LT1 = ON Then MLT OFF
If Timer LT1 = ON Then FUG OFF

This accomplishes the same functionality you currently have, but makes it easier to edit if you change the times your lights turn on and off.

Add, as a safety measure:
If Temp < 70 Then HET OFF

This prevents your heater from cooking your tank in the event the temp probe fails or become disconnected.

 

[805reef]

thanks for the input guys! I changed FeedA to 000, and FeedB i am planning on using for water changes. i added the suggestions by RussM. thanks alot!

 

[ciphros]

<a href=showthread.php?s=&postid=15240928#post15240928 target=_blank>Originally posted</a> by 805reef
thanks for the input guys! I changed FeedA to 000, and FeedB i am planning on using for water changes. i added the suggestions by RussM. thanks alot!

Rather than use a feed timer for water change, you may want to consider using a dummy timer. I use a MNT timer for "tank maintance" Then statements like:
if Timer MNT = ON Then ALM OFF
if Timer MNT = ON Then FAN ON
if Timer MNT = ON Then HET OFF
if Timer MNT = ON Then COL OFF

To tell things what state they need to be in when I go to manual control and turn MNT on. I use an initilization statement to make sure that MNT doesn't come on unless I do so manually:

If time >00:00 Then MNT OFF

This way, if you take longer than you expected, you don't have a pump or other device kick on when you aren't ready for it.

 

[RussM]

805reef, I also noticed that you have no alarm conditions set - have you configured email in the AC3 yet?

You should set alarms for high and low temp, high & low pH (assuming you have a pH probe connected)

I also don't care for the use time-based ATO... I greatly prefer the use of float switches so that ATO operation is based on actual evaporation losses.

 

[wes888]

Ok, here's the program I have for my AC Jr.

LT1 = A1 Power compacts
LT2 = A2 Metal halide
MON = A3 Moonlight
HET = A4 Heater
FAN = A5 Fan
FIL = A6 Filter
KOR = A7 Koralia
PIC = A8 Fuge light

If Time > 07:00 Then LT1 ON
If Time > 08:00 Then LT1 OFF
If Time > 08:00 Then LT2 ON
If Time > 16:00 Then LT2 OFF
If Time > 16:00 Then LT1 ON
If Time > 19:00 Then LT2 OFF
If Time > 19:00 Then MON ON
If Time > 07:00 Then MON OFF
If Time > 20:00 Then PIC ON
If Time > 06:00 Then PIC OFF
If Temp < 76.5 Then HET ON
If Temp > 77.0 Then HET OFF
If Temp < 72.0 Then HET OFF
If Temp > 77.5 Then FAN ON
If Temp < 77.0 Then FAN OFF
If Temp > 85.0 Then FAN OFF
If Temp > 82.0 Then LT1 OFF
If Temp > 82.0 Then LT2 OFF
If Time > 00:00 Then FIL ON
If Time > 00:00 Then KOR ON
If FeedA 000 Then FIL OFF
If FeedA 000 Then KOR OFF
If FeedA 000 Then FAN OFF
If FeedA 000 Then HET OFF
If FeedB 000 Then FIL OFF
If FeedB 000 Then KOR OFF
If FeedB 000 Then FAN OFF
If FeedB 000 Then HET OFF

This is the second day that it's been up and it seems to be running fine. But just to be safe, can someone proofread this and tell me if I've overlooked anything? Any suggestions are welcome. Thanks.

 

[805reef]

Okay I am going to add:
IF FeedA 005 Then SKM OFF
because when I keep the skimmer on, the water level in the sump rises and causes the skimmer to skim super wet... so i am going to shut the skimmer off and then give it 5 minutes for the water level to stabilize before turning it back on. is there a way to make the skimmer have a 5 minute delay when the ac3 is first turned on? such as if there is a power outage or gfci trip? and then when power is restored everything else turns on but i would like the skimmer to wait 5 minutes before turning on